Autoriser le 0 en premier chiffre dans une textbox

Option Explicit

 
' // Cet objet sera vu par tous !

Global WB As Object

 
' // Déclaration de constantes

Global Const taView = 0

Global Const taAdd = 1

Global Const taUpd = 2

Global Const taDel = 3

Option Explicit

 
Dim XL As Object

Private Sub btnAdd_Click()

    Load Form2

    Form2.SetData taAdd, -1

    Form2.Show vbModal

    Reload

End Sub

Private Sub btnDel_Click()

    If List1.ListIndex = -1 Then Exit Sub

    Load Form2

    Form2.SetData taDel, List1.ItemData(List1.ListIndex)

    Form2.Show vbModal

    Reload

End Sub

Private Sub btnQuit_Click()

    Unload Me

End Sub

Private Sub btnUpd_Click()

    If List1.ListIndex = -1 Then Exit Sub

    Load Form2

    Form2.SetData taUpd, List1.ItemData(List1.ListIndex)

    Form2.Show vbModal

    Reload

End Sub

Private Sub btnView_Click()

    If List1.ListIndex = -1 Then Exit Sub

    Load Form2

    Form2.SetData taView, List1.ItemData(List1.ListIndex)

    Form2.Show vbModal

End Sub

Private Sub Reload()

    Dim ws_invite As Object '// Worksheet

    Dim cl_invite As Object '// Range

 
    Set ws_invite = WB.Worksheets("liste_des_invités")

    List1.Clear

    ' //                            La zone des invités

    ' //                            ------vvvvvvvv-----

    For Each cl_invite In ws_invite.Range("A1:A10")

        If cl_invite.Value <> "" Then

            List1.AddItem cl_invite.Value & " " & cl_invite.Offset(0, 1).Value, _

                          List1.ListCount

            ' // La liste par défaut de VB est un peu différente

            ' // de la liste VBA/Excel. La gestion des colonnes est différente

            ' // Mais elle possède un champ Data qui contient un Long.

            ' // Idéale pour mettre notre numéro de ligne.

            List1.ItemData(List1.ListCount - 1) = cl_invite.Row

        End If

    Next

End Sub

Private Sub Form_Load()

    ' // Une bonne fois pour toute !

    Set XL = CreateObject("Excel.Application")

    Set WB = XL.Workbooks.Open("X:\chemin\classeur.xls")

 
    Reload

End Sub

Private Sub Form_Terminate()

    WB.Close False

    XL.Quit

End Sub

Option Explicit

 
Dim m_Ligne As Long

Dim m_TypeAction As Long

Public Sub SetData(TypeAction As Integer, Ligne As Long)

    m_Ligne = Ligne

    m_TypeAction = TypeAction

 
    Select Case m_TypeAction

        Case taView

            btnValide.Visible = False

            btnCancel.Caption = "Fermer"

            btnCancel.Default = True

            Me.Caption = "Consultation d'un invité"

            Text1.Enabled = False

            Text2.Enabled = False

            ' ...

            LoadDataFromExcel

        Case taAdd

            Me.Caption = "Ajout d'un invité à la liste"

        Case taUpd

            Me.Caption = "Modification d'un invité de la liste"

            LoadDataFromExcel

        Case taDel

            Me.Caption = "Radiation d'un invité"

            Text1.Enabled = False

            Text2.Enabled = False

            ' ...

            LoadDataFromExcel

    End Select

 
End Sub

Private Sub LoadDataFromExcel()

    Dim ws_liste As Object

    Set ws_liste = WB.Worksheets("liste_des_invités")

 
    Text1.Text = ws_liste.Cells(m_Ligne, 1)

    Text2.Text = ws_liste.Cells(m_Ligne, 2)

    ' ...

 
End Sub

Private Sub SaveDataToExcel()

    Dim ws_liste As Object

    Set ws_liste = WB.Worksheets("liste_des_invités")

 
    ws_liste.Cells(m_Ligne, 1) = Text1.Text

    ws_liste.Cells(m_Ligne, 2) = Text2.Text

    ' ...

 
    WB.Save

End Sub

Private Sub btnCancel_Click()

    Unload Me

End Sub

Private Sub btnValide_Click()

    Dim ws_liste As Object

    Set ws_liste = WB.Worksheets("liste_des_invités")

 
    Select Case m_TypeAction

        Case taAdd

            If ws_liste.Cells(1, 1).Value = "" Then

                m_Ligne = 1

            Else

                m_Ligne = ws_liste.Cells(1, 1).End(xlDown).Row + 1

            End If

            SaveDataToExcel

        Case taUpd

            SaveDataToExcel

        Case taDel

            ws_liste.Rows(m_Ligne).Delete

            WB.Save

    End Select

 
    Unload Me

End Sub