Case à cocher et calculs conditionnés

Alors là, je suis très déçu   Je t'ai donné une façon de faire pour ne jamais tomber en panne : utiliser l'enregistreur de macro (1), l'aide en ligne (2), un peu de réflexion (3), puis, éventuellement ce forum (4).

Etape (1)
Ouvre donc un classeur vide.
Démarre l'enregistreur de macro.
Ajoute une case à cocher.
Change sa valeur LinkCell.
Arrête l'enregistreur de macro.
Admire ton oeuvre dans l'éditeur VB :

Sub Macro1()
'
' Macro1 Macro
' Macro enregistrée le 26/11/2009 par Zeb Pour Pimousse-62
'
 
'
    ActiveSheet.OLEObjects.Add(ClassType:="Forms.CheckBox.1", Link:=False, _
        DisplayAsIcon:=False, Left:=360, Top:=114, Width:=60, Height:=14.25). _
        Select
End Sub

(Beurk.)

Etape 2
Moi, j'ai tout compris, je me passe de l'étape 2  
Pas toi. Examine avec la touche F1 tous les mots difficiles.

Etape 3
L'étape la plus intéressante !
Alors première constatation, la partie "LinkCell" a été squizée  
Sinon, ça fait
Ajouter (Add) un objet OLE (OLEObjects) à la feuille active (ActiveSheet) de type Boîte à cocher (Forms.CheckBox.1) avec pleins de paramètres inutiles, ou pas.

Bon, réfléchissons donc.
Je ne veux pas d'activetruc. En effet, rien ne garantit que je serai sur la bonne feuille lors de l'invocation de la macro.
La feuille, c'est donc la numéro 1 de mon classeur (décision arbitraire, tu fais comme tu veux).
Et je ne veux pas sélectionner mon objet, je veux une variable dessus pour en changer certaines valeurs (LinkCell en l'occurrence) :

Sub AjouteCoche()
    Dim coche As OLEObject
    Set coche = Worksheets(1).OLEObjects.Add(ClassType:="Forms.CheckBox.1", Left:=360, Top:=114, Width:=60, Height:=14.25)
    coche.LinkedCell = "E7"
End Sub

Et voilà !

En fait, ce n'est pas beau du tout.   Il faudrait mettre la position en paramètre, et la cellule à lier aussi.

Au boulot :

Sub AjouteCoche(cellule As Range)
    Dim o As OLEObject
    Set o = cellule.Worksheet.OLEObjects.Add(ClassType:="Forms.Checkbox.1", _
                                             Left:=cellule.Left, Top:=cellule.Top, _
                                             Width:=cellule.Width, Height:=cellule.Height)
    o.LinkedCell = cellule.Cells(1).Address
End Sub

Etudie bien ce code, il y a quelques petites astuces qui pourront te servir ailleurs.

Ton avis ?
(A part me dire que je suis un de te donner une réponse complète une fois que tu te sois cogné tout le boulot à la main   )