Macro pour changer les dates de reférence d'un graph

Salut,

Si tu es en stage, c'est que tu y es pour apprendre. Je ne vais donc pas te donner la solution. Mais je vais t'aider à la trouver.

T'es d'accord ?

Alors, à l'aide de l'enregistreur de macro, crée un petit graphe sur des données de test. Vois-tu dans le code produit par l'enregistreur où se situe l'affectation des données ? C'est en te servant de cette méthode que tu pourras restreindre l'étendue des données de tes graphes.

Publie ici (relis bien le règlement pour ne pas commettre d'impair   ) le code obtenu, qu'on s'en serve comme support.

Bonjour Zeb,

Je crois que tu as (hélas) un peu raison, j'ai donc fait ce que tu m'as dit et j'obtiens le code suivant:

Range("A12:N13").Select

    ActiveSheet.Shapes.AddChart.Select

    ActiveChart.SetSourceData Source:=Range("'Sheet1'!$A$12:$N$13")

    ActiveChart.ChartType = xlLine

J'avais essayer hier quelque chose d'autre en enregistrant une macro oú je changeais la source du graphique et après j'ai regardé ce que cela donnait... Mais le truc que je n'arrive vraiement pas à comprendre c'est comment faire pour que, en entrant une date, la macro aille chercher cette date sur la ligne des dates et commence à partir de cette date....

Merci d'avance

Alors d'après ton code, il faut référencer un graphique et lui appliquer la méthode SetSourceData(). Bon, personnellement, plutôt que de les pointer à la souris et de laisser le système faie sur l'objet actif, je préfère être plus précis. Seulement, il faut connaître le nom de chaque graphique.

Worksheets("Sheet1").ChartObjets("Graphique 1").Chart.SetSourceData Source:=Range("'Sheet1'!A12:N13")

Comment, tu ne connais pas le nom de tous tes graphiques ?
En voici la liste :

Dim co As ChartObject

Dim s  As String

 
s = "La liste des graphique de la feuille 1"

For Each co In Worksheets(1).ChartObjects

    s = s & vbCrLf & " * " & co.Name

Next

MsgBox s

zone = "A12:N13"

Worksheets("Sheet1").ChartObjets("Graphique 1").Chart.SetSourceData Source:=Range("'Sheet1'!" & zone)

Bon, donc en fait, il juste faut fabriquer la chaîne zone.
Pour cela, il suffit de parcourir tes données...

T'as une idée de comment faire ?

Bonjour,

Désole de ma réponse tardive mais c'était la folie au bureau!
Merci beaucoup de ta réponse, j'ai regardé comment faire mais en faite je crois que je comprend pas très bien l'histoire des noms de graphiques.... Donc forcement je ne vois pas non plus comment faire pour la chaine zone.

Parce que effectivement, ce que je veux créer c'est pour ne pas avoir à pointer la souris.

Mais dans l'ensemble, j'avoue que je suis totalement perdu...

Oki. Pour me suivre, pars d'un classeur vide. Exécute le code La liste des graphique. Tu obtiens exactement rien. C'est normal  

Bon, maintenant, écris un peu de données dans le premier onglet, et crée un graphique basé sur ces données dans cet onglet. Réexécute le code La liste des graphique. Tu obtiens un nom de graphique que tu n'as pourtant pas donné explicitement.

Donc première difficulté, soit se servir des noms qu'Excel donne à ses graphiques, soit décider nous-même de ces noms.

Comprends-tu ce premier problème ?

ok, quand j'excute cette macro, excel m'envoie un message avec la liste des graphiques de la feuille. Effectivement, il donne des noms que je n'ai pas du tout mis.

Il faudrait donc qu'à un moment donné il me demande le nom du graphique que je veux transformer pour au'il aille choisire les bonnes données ou quelque chose comme ca?

Ah... En voilà un qui à tout compris !  

Donc maintenant, il va falloir identifier quel(s) graphique(s) tu veux changer.
Moi, je serais partisan d'imposer des noms explicites à chaque graphe.

Voilà comment l'enregistreur de macro voit la création d'un graphe tout bête :

Charts.Add

ActiveChart.ChartType = xlColumnClustered

ActiveChart.SetSourceData Source:=Sheets("Feuil1").Range("A12:N13"), PlotBy:=xlRows

ActiveChart.Location Where:=xlLocationAsObject, Name:="Feuil1"

Le revoilà à faire confiance au fait qu'un objet plutôt qu'un autre est actif. (Il m'énerve cet enregistreur de macro   )

Dim ch As Chart

Set ch = Charts.Add

ch.ChartType = xlColumnClustered

ch.SetSourceData Source:=Sheets("Feuil1").Range("A12:N13"), PlotBy:=xlRows

ch.Location Where:=xlLocationAsObject, Name:="Feuil1"

J'utilise une variable - C'est quand même plus "informatique" - que j'initialise au moment de la création.
J'exécute ce code pas-à-pas. Et je m'aperçois qu'il fabrique un onglet de type Chart et qu'à la ligne 5, il transforme mon onglet en objet de feuille  

On va réécrire tout ça, avec un objet ChartObjet, directement !

Dim sh As Worksheet

Dim co As ChartObject

 
Set sh = Worksheets(1)

 
Set co = sh.ChartObjects.Add(100, 100, 200, 100)

co.Name = "Un graphe pour Matthieu"

co.Chart.ChartType = xlColumnClustered

co.Chart.SetSourceData Source:=sh.Range("A12:N13"), PlotBy:=xlRows

Ah, c'est pas mal hein ? Et surtout, on a nommé nous même notre graphe. Comme ça, on peut changer la plage des données facilement :

Dim sh As Worksheet

Dim co As ChartObject

 
Set sh = Worksheets(1)

 
Set co = sh.ChartObjects("Un graphe pour Matthieu")

co.Chart.SetSourceData Source:=sh.Range("A12:B13")

Et voilà  

------------------------------------

Bon, évidemment, il faut avoir nommé soi-même ses graphes à la création, d'une part, et surtout, il faut avoir des noms uniques.  

Or, donc, comment nommé ses graphes quand ils sont déjà créés ?
Voià une question intéressante.

Je te laisse chercher un peu. Tu as presque tous les éléments. Il faut :

Savoir parcourir tous les graphes (cf. La liste des graphique de la feuille 1)

Savoir en sélectionner un (l'enregistreur t'a montré comment faire)

Savoir afficher le nom actuel du graphe

Savoir demander à l'utilisateur d'en changer (ah, j'ai encore des choses à t'apprendre si tu ne sais pas te débrouiller   )

Quand tu sauras faire ça, il restera à gérer les dates et tu auras trouvé une solution à ton problème de départ.

Alors quand j'excute ma nouvelle macro, je commencé par mettre la liste des graphes mais il me les affiche pas tous... (6 au lieu de 25).

Mon problème c'est que je n'arrive pas a selectionner un graphique particulier pour en chager le nom, je n'arrive pas à comprendre comment faire pour qu'il m'affiche le nom de tel ou tel graphique... Bref j'arrive pas a grand chose, je pense comprendre le raisonement mais je suis très loin de réussir a le traduire en VBA

Fais voir comment tu fais !

Alors je commence par tenter d'afficher la liste des graphs:

Dim co As ChartObject

    Dim s  As String

 
    s = "La liste des graphique de la feuille 1"

    For Each co In Worksheets(1).ChartObjects

        s = s & vbCrLf & " * " & co.Name

    Next

    MsgBox s

Donc la il m'affiche certains graphs, et après j'essaye de d'en nommer un mais je suis pas sur de comprendre très bien le code sur leque je m'appuie:

Set co = sh.ChartObjects.Add(100, 100, 200, 100)

    co.Name = "Un graphe pour Matthieu"

    co.Chart.ChartType = xlColumnClustered

    co.Chart.SetSourceData Source:=sh.Range("A12:N13"), PlotBy:=xlRows

Est ce qu'il nomme "un graph pour Matthieu" le graphe qui a comme source "A12:N13" ? Et à quoi sert la ligne Add100, 100,200,100?

La j'ai l'impression qu'avec mon code il me donne une liste de graph puis me creer un graph à chaque fois basé sur A12:N13...

Ohlala !!!!
Il ne faut pas exécuter bêtement les codes que je te propose, il faut les étudier et les comprendre !!!!

Ton nouvel ami est la touche F1.

Alors tu vas te balader sur chacun des mots de ton code, et tu vas appuyer sur F1.
Quand je le fais pour Add par exemple, j'obtiens :



Méthode Add telle qu'elle s'applique à l'objet ChartObjects.

Cette méthode crée un graphique incorporé. Elle renvoie un objet ChartObject.



expression Obligatoire. Expression qui renvoie un objet ChartObjects.

Left, Top Argument de type Double obligatoire. Coordonnées initiales du nouvel objet (en points), par rapport au coin supérieur gauche de la cellule A1 d'une feuille de calcul ou du coin supérieur gauche d'un graphique.

Width, Height Argument de type Double obligatoire. Taille initiale du nouvel objet, en points.



A cette très enrichissante lecture, je me dis que ce n'est pas la méthode Add qu'il faut utiliser. N'est-ce pas ?

Je reprends :
1°) parcourir tous les graphes
2°) en sélectionner un
3°) afficher le nom actuel du graphe
4°) demander à l'utilisateur d'en changer

Dim co  As ChartObject
Dim nom As String
 
' // Parcourir tous les graphiques de la feuille 1
For Each co In Worksheets(1).ChartObjects
    ' // En sélectionner un :
    co.Activate
    co.Chart.ChartArea.Select
 
    ' // Afficher son nom
    If MsgBox("Voulez-vous changer le nom du graphique " & co.Name & " ?", _
              vbQuestion Or vbYesNo, "Graphique") = vbYes Then
        ' // Oui, il veut !
        nom = InputBox("Nouveau nom")
 
        ' // Si quelque chose a été saisi et que l'utilisateur n'a pas annulé...
        If nom <> "" Then
            ' // ... On change le nom
            co.Name = nom
        End If
    End If
Next

A étudier  

Alleluia, ca marche!!

Je crois comprendre à peu près comment le code marche, j'ai rajouté une partie pour qu'il m'affiche d'abord le nom de tous les graphes présent.

Il faut maintenant que je fasse un code pour choisir le graphique que je veux renommer, sinon avec la boucle "for", il me redemande à chaque fois de tous les renommer...

Je pensais donc faire avec un "If", tel ou tel graph est activé alors le code me demande de changer el nom de ce graph.

MsgBox ("Selectionnez un graph")

    ActiveSheet.ChartObjects("Chart 3 ").Activate

    ActiveChart.SeriesCollection(1).Select

 
    If co("Chart 3 ").ChartObjects = Activate Then

        co.Activate

        co.Chart.ChartArea.Select

Et je continue avec le code précedent, mais j'ai un probleme avec mon if et avec le fait qu j'arrive pas a selctionner le graph que je veux autrement que en mettant son nom dans le code...

 

Voila comment on fait pour être sûr de ce qui est sélectionné ou pas. Ensuite, on peut travailler dessus :

Dim co As ChartObject
 
If TypeOf Selection Is ChartObject Then
    Set co = Selection
ElseIf TypeOf Selection Is ChartArea Or _
       TypeOf Selection Is Axis Or _
       TypeOf Selection Is Legend Or _
       TypeOf Selection Is PlotArea Then
    Set co = Selection.Parent.Parent
ElseIf TypeOf Selection Is Gridlines Or _
       TypeOf Selection Is Series Or _
       TypeOf Selection Is AxisTitle Then
    Set co = Selection.Parent.Parent.Parent
ElseIf TypeOf Selection Is DataLabels Then
    Set co = Selection.Parent.Parent.Parent.Parent
Else
    MsgBox "Vous avez sélectionné un '" & TypeName(Selection) & "', qui n'est pas (encore) pris en compte"
    Exit Sub
End If
co.Activate
co.Chart.ChartArea.Select
MsgBox "L'objet sélectionné est '" & o.Name & "'" & vbCr & " (en fait, c'est la zone de chart du chart de l'objet)"

Bonjour,

Merci encore une fois de ta réponse,

Je ne comprends pas trés bien ton dernier code: ce que je crois comprendre c'est qu'avant de l'excuter je clique sur un objet et si c'est un graph il me donne le non de ce graph. Cependant, quand je l'execute, il y a un problème au niveau de la ligne 20, il me dit que la variable n'est pas "set" alors que j'ai l'impression qu'elle l'est en ligne 4.

Salut,

En fait, quand tu cliques sur un graphe pour le sélectionner, tu n'es pas sûr de l'objet exact sur lequel tu es. Est-ce le graphe, l'objet conteneur du graphe, la zone de dessin du graphe, le titre, etc.

D'où la succession de tests et de Sets pour choisir le bon objet.

Il y avait une petite coquille dans mon code, j'avais écrit xo pour co. C'est mal. J'ai corrigé.
Mais il y a pire. Tu n'as pas utilisé l'option explicit, ce qui t'aurait permis de t'en apercevoir toi-même !!!! C'est très mal. Alors, utilise-la.

--------------

Ça y est ? Tu peux renommer tes graphes, et changer leurs données comme tu l'entends ?

Bonjour,

Je me suis focalisé sur la ligne 20 pour comprendre ce qui aller pas et je ne suis pas aller plus haut  

Donc maintenant je peux renomer mes graphes, ce qui me semble pas mal du tout. J'ai rajouté quelque chose pour que si je ne change pas le nom il continue quand meme.

Après, je rajoute une ligne pour demander a l'utilisateur s'il veut changer la source, puis une ligne pour changer la source.

On en arrive donc au deuxieme problème, comment faire pour que je décide des dates, sans rentrer dans le code.

Mon deuxieme probleme est que j'ai une série de date, et en dessous j'ai toutes les données, il faut donc que mon graphes prennent les bonnes données.

Je me disais de peut etre essayer de demander a l'utilisateur de mettre un "range" pour les données que la macro irait rechercher avec le "setcourcedate". Ca serait une premiere étape pour ensuite n'avoir qu'à rentrer les dates et que ma macro aille chercher les données.

Bon. On a donc un nom explicite pour chaque graphe.
Et le graphe "grafdaté" peut changer en fonction des dates.

Bon. Ben voilà :

Dim plage As Range
Worksheets(1).ChartObjets("grafdaté").Chart.SetSourceData Source:=plage

Y'a plus qu'à alimenter la zone plage. Facile :

plage = vide
Pour toutes les cellules concernées,
Si date est correcte Alors  plage = plage + cellule

For Each cell In Range("A1:E1")
    If cell.Column <> 3 Then
        Set plage = Union(zone, cell)
    End If
Next

Bon, la fonction Union() n'est pas fichue de traiter des arguments vides. C'est nul. Donc on le gère :

For Each cell In Range("A1:E1")
    If cell.Column <> 3 Then
        If plage Is Nothing Then
            Set plage = cell
        Else
            Set plage = Union(plage, cell)
        End
    End If
Next

Bon, ma condition c'est que je n'aime pas les colonnes 3.
Toi, c'est un problème de choix dans la date.

Tu vois ce qui te reste à faire ?

Bonjour,

J'aime beaucoup ta contrepétrie de mon probléme de "choix dans la date" mais par contre je ne comprend pas trés bien ce que fait ce programme, donc je vois pas trop ce que je dois faire avec...

Pour remplir la variable plage, je parcours la zone "A1:E1", et je prends toutes les cellules qui ne sont pas dans la colonne 3.

Toi, tu dois parcourir la zone ?????, et tu dois prendre toutes les cellules qui correspondent ????? à telle période.

Comme je ne connais pas l'organisation de ton fichier, je te laisse le faire.
(De toute façon, je préfère que tu le fasses toi-même).

Vois-tu un peu mieux ce que tu as à faire ?

Bonjour,

Je crois comprendre ce que fait le code. Ca veut dire que si j'ai une ligne avec toutes mes dates et en dessous les données pour chacun des graphes (une ligne pour un graph). Il faut que je fasse un changement de source de ce graphe la:

Set sh = Worksheets(3)

 
Set co = sh.ChartObjects(nom)

co.Chart.SetSourceData Source:=sh.Range(plage)

Et avant, il faut que je prennent les bonnes données quand je "set" ma plage. C'est donc à ce moment que je dois pouvoir rentrer les dates de début et de fin, qu'en les notant, ma boucle for ne travaille que pour ce range, tout en allant cherchant les bonnes données (ca ca doit etre grace au nom qu j'y arrive si je ne me trompe pas).

Je pensais donc faire queque chose comme ca:

Dim datedébut As Date

 
datedébut = InputBox("Entrez la date de début")

  If datedébut <> "" Then

    Cells.Find(What:="datedébut", After:=ActiveCell, LookIn:=xlFormulas, _

    LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _

    MatchCase:=False, SearchFormat:=False).Activate

  End If

Et pareil pour la date de la fin et après je sais pas torp comment faire pour que mon for ne cherche que pour les bonnes dates...

Bon, tu cherches trop compliqué.

Regarde :

Dim Periode(0 To 1) As Date

 
' // Je mets les dates que je veux, na !

Periode(0) = CDate("1 février 2011")

Periode(1) = CDate("14 février 2011")

 
Dim plage_totale As Range

Dim plage_date   As Range

Dim plage_graphe As Range

 
' // La ligne 12 contient les dates

' // La ligne 13 contient les valeurs

' // C'est ça ?

Set plage_totale = ws.Range("A12:N13")

Set plage_date = plage_totale.Rows(1)

 
Dim cell As Range

Dim cell_ajoute_moi As Range

 
' // On parcourt toutes les dates.

For Each cell In plage_date.Cells

    If CDate(cell.Value) >= Periode(0) And _

       CDate(cell.Value) <= Periode(1) Then

        ' // La cellule qu'il faut ajouter est juste en dessous de cell

        ' // Pour se décaler d'une ligne, on utilise Offset qui en anglais signifie : ?????

        Set cell_ajoute_moi = cell.Offset(1)

 
        ....

 
    End If

Next

Bonjour,

Je me demandais s'il existe une boucle pour que je fasse : tant que la date n'est pas bonne il fasse tourner la boucle pour reduire les periodes?

Si je comprend bien ton code, il faut qu'apres je mete le code pour "set" une nouvel plage (en m'inspirant de ce que tu m'as dit à propos de union etc) et il faut que je fasse ca en étant sur qu'il réduise la zone pour les valeurs aussi.

Donc a la fin il faut que je set la plage date, set la plage total et fasse le changement de source sur cette nouvelle plage?

Oui, c'est exactement ça.
Mais tu as besoin des dates ET des valeurs ?

Alors le code devient :

For Each cell In plage_date.Cells

    If CDate(cell.Value) >= Periode(0) And _

      CDate(cell.Value) <= Periode(1) Then

        Set cell_ajoute_moi_je_suis_une_date   = cell

        Set cell_ajoute_moi_je_suis_une_valeur = cell.Offset(1)

 
        ....

 
    End If

Next

 

Bonjour,

Alors maintenant j'arrive a changer les valeur du graph que j'ai selectionné, le problème c'est qu'il ne prend pas les valeur que je veux et surtout il ne prend pas de valuer du tout j'ai l'impression.. Il ne prend que les dates et il met un titre au graph ( qui est la premiere date en faite...). En faite la je crois que je me perd un peu dans les differents code, dans ce que je dois faire, je vois plus du tout ou je dois aller, je sais meme plus ce que je dois faire...

Oki.

Fais-toi une feuille très simple, avec des données type, un graphe bien nommé et ta macro. Et révise-le tout.

Si tu as encore des problèmes, publie ici le code complet de la macro, et explicite-nous très précisément l'organisation de tes données.

A te lire.

Bonjour,

J'ai fait ce que tu m'as dit de faire mais j'ai un autre probleme qui est que excel plante juste apres que je renomme mon graph, et je ne comprend pas pourquoi...

Pour ce qui de ma "vrai" macro:

Mon fichier est organisé de la facon suivante: sur la troisième page de mon fichier j'ai 25 graphs en haut de la page, grosso modo entre B2 et X100.

En dessous à la ligne 151 j'ai une première série de dates : de D150 à BM 150 ( du 30/12/2005 au 30/01/2011). En dessous entre la ligne 151 et 168 j'ai les donné qui vont avec ces dates pour completer le graph. Sachant que la colonne juste à gauche donne à quoi correspondent ces données ( ex PIB de Chine).

Après à partir de la ligne 171 j'ai une nouvelle serie de dates, pour certaine valeures (ligne 171 à174) spécifique à quelques graphs. J'ai la meme chose entre les lignes 176 et 179 (176 les dates et en dessous les valeurs), aux lignes 180 à 183, 185 à187 et 189 à 191.

En gros pour faire cette macro j'ai importé plein de données puis j'ai fait des graphs en selectionnant les bonnes valeurs. Le truc c'est qu'on me demande souvent de sortir ces graphs pour une certaine période d'ou lobjet de ma question initiale. J'aimerai bien m'en servir dans d'autre contexte ou je dois updater des graphs en selectionnant des données qui sont géneralement sur une autre feuille...

Mon code pour l'instant donne ca:

Sub Select_graph()

'

' Select_graph Macro

'

    Dim co As ChartObject

    Dim s  As String

    Dim nom As String

    Dim sh As Worksheet

    Dim plage As Range

    Dim datedébut As Date

 
 
 
        s = "La liste des graphique de la feuille 3"

        For Each co In Worksheets(3).ChartObjects

            s = s & vbCrLf & " * " & co.Name

        Next

        MsgBox s

 
 
    If TypeOf Selection Is ChartObject Then

        Set co = Selection

    ElseIf TypeOf Selection Is ChartArea Or _

          TypeOf Selection Is Axis Or _

          TypeOf Selection Is Legend Or _

          TypeOf Selection Is PlotArea Then

        Set co = Selection.Parent.Parent

    ElseIf TypeOf Selection Is Gridlines Or _

          TypeOf Selection Is Series Or _

          TypeOf Selection Is AxisTitle Then

        Set co = Selection.Parent.Parent.Parent

    ElseIf TypeOf Selection Is DataLabels Then

        Set co = Selection.Parent.Parent.Parent.Parent

    Else

        MsgBox "Vous avez sélectionné un '" & TypeName(Selection) & "', qui n'est pas (encore) pris en compte"

        Exit Sub

    End If

    co.Activate

    co.Chart.ChartArea.Select

    MsgBox "L'objet sélectionné est '" & co.Name & "'" & vbCr & " (en fait, c'est la zone de chart du chart de l'objet)"

 
    If MsgBox("Voulez-vous changer le nom du graphique " & co.Name & " ?", _

                  vbQuestion Or vbYesNo, "Graphique") = vbYes Or vbNo Then

            nom = InputBox("Nouveau nom")

 
                       If nom <> "" Then

                ' // ... On change le nom

                co.Name = nom

 
                    End If

            End If

 
 
       Dim Periode(0 To 1) As Date

 
 
 
    ' // Je mets les dates que je veux

    Periode(0) = CDate("12/30/2005")

    Periode(1) = CDate("03/31/2006")

 
    Dim plage_totale As Range

    Dim plage_date  As Range

    Dim plage_graphe As Range

 
    ' // La ligne 12 contient les dates

    ' // La ligne 13 contient les valeurs

    Set plage_totale = Worksheets(3).Range("D150:E191")

    Set plage_date = plage_totale.Rows(1)

 
    Dim cell As Range

    Dim cell_ajoute_moi As Range

 
    ' // On parcourt toutes les dates.

    For Each cell In plage_date.Cells

        If CDate(cell.Value) >= Periode(0) And _

          CDate(cell.Value) <= Periode(1) Then

                       Set cell_ajoute_moi = cell.Offset(1)

            Set cell_ajoute_moi = cell.Offset(1)

            Set cell_ajoute_moi = cell.Offset(1)

            Set cell_ajoute_moi = cell.Offset(1)

 
                If plage Is Nothing Then

                 Set plage = cell

                Else

                    Set plage = Union(plage, cell)

                End If

 
        End If

 
    Set zone = plage

    ActiveChart.SetSourceData Source:=zone

 
 
    Next

 
End Sub

Voila, c'est à peu près tout je crois,

En tout cas, merci encore pour ton aide

Salut,

Comment ça le renommage ne fonctionne plus ?
Il fonctionnait avant ?

If MsgBox("blabla", vbQuestion Or vbYesNo, "Graphique" ) = vbYes Or vbNo Then

C'est pas moi qui t'ai dit de faire ça   Vire le Or vbNo et réfléchis au pourquoi  

Eh, pourquoi tu fais 4 fois la même chose de la ligne 78 à la ligne 81 ?
Et lignes 84 et 86, tu ajoutes la cellule cell, qui est la cellule de parcours, et non pas celle qu'on veut ajouter. (Je rappelle que la cellule qu'on veux ajouter s'appelle cell_ajoute_moi   ).

Tu sais, je pense qu'on peut simplifier les lignes 91-92  

------------



Pour rappel, si par ailleurs (ben oui, qu'est-ce qu'elle fait là la procédure de renommage ? - Faut la mettre à part) on imposait des noms à nos graphes, c'était en pour changer la SourceData de façon explicite, comme ça :

ChartObjects("le_nom").Chart.SetSourceData Source:=plage